CMake是一个跨平台、开源的构建工具,在C/C++项目中有广泛应用。本文首先介绍CMake及常用指令,并结合工作时需要用到的Qt 5,给出一个完整的CMake项目配置。

CMake简介

CMake如其名”Cross-platform Make”,是一个 跨平台、开源 的构建工具。与make不同,CMake并不直接构建软件,而是生成用于构建的Makefile、.sln等工程文件,相当于高阶构建工具。

与另一构建工具Automake相比,CMake使用上更方便,支持更多的编译套件(Ninja、VS等)。许多编辑器和IDE,如VS Code(宇宙第一编辑器/IDE)、Clion、Visual Studio等都内置了对CMake的支持。特别的,CMake已经是QT 6的默认构建工具,官方给出从qmake迁移的理由是CMake成熟稳定、用户基数大生态完善。因此,对于需要跨平台编译运行的C/C++项目,很推荐学习和使用CMake作为构建工具,能方便的转换成各种IDE项目,团队成员无需切换编辑器/IDE即可工作。

值得一提的是,CMake由Kitware公司开发和维护,VTK和ParaView等知名开源产品均出自该公司。从这方面看,CMake也算出身名门,因此能很快流行开来。

CMake命令

CMake基于CMakeLists.txt文件来生成对应目标(generator)的构建文件,一个标准的CMake项目构建操作为(命令行方式):

cd PROJECT_DIR
cmake
make TARGET

或者使用用CMake GUI:

CMake-GUI操作示意图
CMake-GUI操作示意图

然后使用VS打开生成的.sln项目,即可编译、运行和调试项目。

Linux/Unix/MacOS平台上,CMake默认生成标准的makefile;Windows平台上则会检测Visual Studio版本,生成对应的VS .sln项目工程文件(在MSYS/Cygwin/WSL环境下执行除外)。可以使用 -G 选项切换生成目标,例如生成Ninja构建文件:

cmake . -G Ninja
ninja TARGET

CMake一个非常棒的特性是“外部构建”(out-of-source build),即支持在源码目录外构建。由于这个特性,以及CMake生成的makefile没有clean命令,一般来说都推荐在单独的build目录中构建:

mkdir -p build
cd $_
cmake ..
make TARGET -j4

如果使用CMake GUI,Browse Build时请选择单独的构建目录。

命令行方式下编译Debug/Release版本、传递C++编译参数,请使用 -D 选项,例如:

cmake .. -DCMAKE_BUILD_TYPE=Release
make TARGET -j4

一些内置的宏定义参数可参考下文的环境变量。

如果是生成VS项目,则只需在VS中选择构建版本、设置编译和链接参数即可。

CMake常见指令

CMake基于CMakeLists.txt文件生成项目构建文件,因此编写CMakeLists.txt文件是CMake项目的核心。本小节介绍一些用在CMakeLists.txt文件中的常用指令。

CMakeLists.txt 使用  # 作为注释,# 所在行后续字符均作为注释被忽略

  • cmake_minimum_required

一般这条指令出现在文件的最前面,用来指定项目支持的最低版本。对于Qt 5项目,建议为:cmake_minimum_required(VERSION 3.7)

  • project

指定项目名称及属性。C/C++项目的建议值为:project(项目名称 C CXX)

  • set

定义一些变量、宏的值。该指令一般会出现多次,例如设置C++语法标准:set(CMAKE_CXX_STANDARD 11)。相反的指令是unset。

  • if…else[if]…endif

条件控制语句,注意指令后的括号不可省略:

if (WIN32)
xxxx
else() # 括号不可省略
xxxx
endif()

  • find_package

查找指定模块,例如OpenMP。Qt 5项目一般需要:find_package(Qt5 COMPONENTS Widgets REQUIRED)

  • include_directories

添加头文件include路径,一个更推荐使用的指令是 target_include_directories,其不污染后续目标的include路径,且能精细控制是否暴露依赖的包含路径。但是 target_include_directories 需要CMake 3.13 版本才支持,在Visual Studio 2017中使用会有问题。

  •  link_directories

设置链接库的路径,更推荐的指令是 target_link_directories,理由见 include_directories

  • aux_source_directory

将指定目录下的源文件添加到变量中,例如:aux_source_directory(./src SRC)。注意该命令不会递归包含子目录源文件。

  • file

file命令是一个功能丰富的目录和文件操作指令,例如递归找出目录下的所有源文件保存到SRC变量中:file(GLOB_RECURSE SRC "src/*.cpp" "src/*/*.cpp")

相对于把每个需要编译的文件添加到CMakeLists.txt中,aux_source_directory 和 file 等指令可方便的引入多个文件,但其弊端之一是CMake不能感知文件变化。当新增文件、文件被删除、重命名时需刷新CMake缓存才能被应用到项目中。

  • find_library

查找指定库的路径并保存到变量中。

  • add_custom_command

添加自定义命令,可用于构建前进行moc,构建后拷贝文件等用途。

  • add_subdirectory

添加一个需要构建的子目录,子目录下有CMakeLists.txt文件设定好构建规则。

  • add_executable

构建可执行程序,一般项目的主CMakeLists.txt中会有这条指令。

  • add_library

构建动态或静态库,一般存在于子目录或者库的CMakeLists.txt文件中。

  • message

可在cmake构建时输出信息。

CMakeLists.txt文件中指令不区分大小写,但一般来说同一个文件中指令应保持大小写风格一致。

更多指令可参考 CMake官方文档

常用环境变量

本小节介绍几个常用的环境变量(编译宏)。

  • CMAKE_BUILD_TYPE:  指定构建类型,常用值为 Debug、Release、RelWithDebInfo 和 MinSizeRel;
  • CMAKE_C(XX)_FLAGS:传递给C/C++编译器的编译选项,例如输出所有警告: -DCMAKE_CXX_FLAGS="-Wall"
  • – CMAKE_EXE/MODULE/_LINKER_FLAGS:传递给C/C++链接器的编译选项,例如指定链接数学库:-DCMAKE_LINKER_FLAGS="-lmath"

Qt应用示例

本节结合工作时需要用到的Qt 5,介绍Qt 5工程中CMake的使用方式。

新建Qt项目时,可以选择CMake作为构建工具:

Qt新建项目使用CMake
Qt新建项目使用CMake

生成项目后,项目文件夹将出现CMakeLists.txt和CMakeLists.txt.user两个文件,熟悉的.pro文件没有了(CMakeLists.txt.user充当了Qt Creator工程文件的角色,其他IDE用不到,可删除)。

但需要注意的是,此时Qt Creator中编译项目是没问题的,但是在CLion/VS Code中打开,或者生成Visual Studio用的.sln文件会有问题,因为CMake无法检测到Qt是否安装及其安装路径。

解决办法便是在 project 指令后增加如下指令告知Qt的安装位置:

# 具体路径请根据自身情况替换
set(QT_MSVC_PATH "C:\\Qt\\Qt5.12.8\\5.12.8\\msvc2017_64")
set(CMAKE_PREFIX_PATH "${QT_MSVC_PATH}/lib/cmake")

然后再次运行 cmake 指令或者使用CMake GUI重新运行,构建文件夹下便能正常生成.sln项目文件。

VS中编译好后,运行时会提示无法找到Qt相关的dll导致程序不能正常运行。解决办法包括:

1. 设置VS选项,将Qt的dll路径包含进去;
2. 将Qt相关dll拷贝到编译输出文件夹;
3. 设置CMake,使其能自动复制所需要的dll。

这里介绍第三种方式,原理是借助Qt自带的windeployqt.exe程序自动部署程序所需dll到目标文件夹。具体操作为,在项目根目录的CMakeLists.txt最后添加部署dll的指令:

set(QT_BIN_PATH "${QT_MSVC_PATH}/bin")
function(windeployqt target)

# POST_BUILD step
# - after build, we have a bin/lib for analyzing qt dependencies
# - we run windeployqt on target and deploy Qt libs

add_custom_command(TARGET ${target} POST_BUILD
COMMAND "${QT_BIN_PATH}/windeployqt.exe"
--verbose 1
#--release # uncomment this line if built with Release
#--no-svg
#--no-angle
#--no-opengl
#--no-opengl-sw
#--no-compiler-runtime
#--no-system-d3d-compiler
\"$<TARGET_FILE:${target}>\"
COMMENT "Deploying Qt libraries using windeployqt for compilation target '${target}' ..."
)

endfunction()

if (WIN32)
  windeployqt(${PROJECT_NAME})
endif()

最后,转换成VS项目时,默认是Console项目,运行时会有cmd窗口。一个解决办法是在生成可执行文件时设置目标为 WIN32:

add_executable(${PROJECT_NAME} WIN32 xxxx)

一个完整的Qt 5项目CMakeLists.txt

以下是一个适用于Windows平台的Qt 5项目完整CMakeLists.txt,实际使用时请替换名字和Qt 5安装路径等:

cmake_minimum_required(VERSION 3.7)

# 请将myproject改成实际的应用名字
project(myproject LANGUAGES CXX)

set(CMAKE_INCLUDE_CURRENT_DIR ON)

# 请更改为实际的Qt安装目录
set(QT_MSVC_PATH "C:\\Qt\\Qt5.12.8\\5.12.8\\msvc2017_64")
set(CMAKE_PREFIX_PATH "${QT_MSVC_PATH}/lib/cmake")
set(QT_BIN_PATH "${QT_MSVC_PATH}/bin")

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

find_package(Qt5 COMPONENTS Widgets REQUIRED)

# 默认Release构建
if (NOT CMAKE_BUILD_TYPE)
    set( CMAKE_BUILD_TYPE "Release" )
endif()
message("build type: ${CMAKE_BUILD_TYPE}")

# 按照自己的项目结构添加文件
# 也可使用file/aux_source_directory批量引入,注意不要引入自动生成的文件!
add_executable(${PROJECT_NAME} WIN32
  main.cpp
  mainwindow.cpp
  mainwindow.h
)

target_link_libraries(${PROJECT_NAME} PRIVATE Qt5::Widgets)

function(windeployqt target)
# POST_BUILD step
add_custom_command(TARGET ${target} POST_BUILD
COMMAND "${QT_BIN_PATH}/windeployqt.exe"
--verbose 1
#--release 
#--no-svg
#--no-angle
#--no-opengl
#--no-opengl-sw
#--no-compiler-runtime
#--no-system-d3d-compiler
\"$<TARGET_FILE:${target}>\"
COMMENT "Deploying Qt libraries using windeployqt for compilation target '${target}' ..."
)

endfunction()

if (WIN32)
  windeployqt(${PROJECT_NAME})
endif()
````

通过上面的配置,我们的Qt项目既可在Qt Creator中正常编译运行,也可在CLion/Visual Studio中正常编译运行而 无需安装Qt插件

参考

1. CMake官网

2. CMake教程

3. CMake FAQ

4. CMake指定编译器